Example: Changing the Font
|
10 ! *********************************************************************
20 ! Example: Changing the Font
30 !
40 ! This program shows how to change the font on displayed
50 ! text. The numbers shown in (), such as 6 BY 12, show
60 ! the number of pixels wide X number of pixels high.
70 !
80 ! *******************************************************
90 !
100 DIM Font$[100],Text$[100]
110 !
120 DATA "6 BY 12", "Example Text (6 BY 12)"
130 DATA "6 BY 12,BOLD", "Example Text (6 BY 12, BOLD)"
140 DATA "8 BY 16", "Example Text (8 BY 16)"
150 DATA "8 BY 16,BOLD", "Example Text (8 BY 16, BOLD)"
160 DATA "9 BY 15", "Example Text (9 BY 15)"
170 DATA "9 BY 15,BOLD", "Example Text (9 BY 15, BOLD)"
180 DATA "10 BY 20", "Example Text (10 BY 20)"
190 DATA "10 BY 20,BOLD", "Example Text (10 BY 20, BOLD)"
200 DATA "18 BY 30", "Example Text (18 BY 30)"
210 DATA "18 BY 30,BOLD", "Example Text (18 BY 30, BOLD)"
220 DATA "end","end"
230 !
240 ASSIGN @Disp TO WIDGET "LABEL";SET ("X":50,"Y":25,"WIDTH":500,"HEIGHT":100,"TITLE":" Example: Changing the Font")
250 CONTROL @Disp;SET ("SYSTEM MENU":"Quit")
260 ON EVENT @Disp,"SYSTEM MENU" GOTO Finis
270 Top: !
280 RESTORE
290 LOOP
300 READ Font$,Text$
310 EXIT IF Font$="end"
320 CONTROL @Disp;SET ("VALUE":Text$,"FONT":Font$)
330 WAIT .75
340 END LOOP
350 GOTO Top
360 Finis: !
370 ASSIGN @Disp TO * ! Delete LABEL widget
380 END
