10 ! *********************************************************************
20 ! Example: LIST Widget
30 !
40 ! This program creates a LIST widget with a defined
50 ! list of animals. When the user selects an animal's
60 ! name, an INFORMATION dialog appears that displays
70 ! the name of the animal selected.
80 !
90 ! *******************************************************
100 !
110 DIM L$(1:5)[26]
120 INTEGER N
130 !
140 DATA " Aardvark"," Sidewinder"," Kiwi"," Pangolin"," Marmoset"
150 READ L$(*)
160 !
170 ASSIGN @List TO WIDGET "LIST";SET ("SYSTEM MENU":"Quit")
180 CONTROL @List;SET ("X":100,"Y":50,"WIDTH":400,"BACKGROUND":1)
190 CONTROL @List;SET ("TITLE":"Example: LIST Widget - Select Your Favorite Animal")
200 CONTROL @List;SET ("ITEMS":L$(*))
210 !
220 ON EVENT @List,"SELECTION" GOSUB Handler
230 ON EVENT @List,"SYSTEM MENU" GOTO Finis
240 !
250 LOOP
260 WAIT FOR EVENT
270 END LOOP
280 STOP
290 !
300 Handler: !
310 STATUS @List;RETURN ("SELECTION":Sel)
320 DIALOG "INFORMATION",L$(Sel+1);SET ("TITLE":" Animal Selected")
330 RETURN
340 !
350 Finis: !
360 ASSIGN @List TO * ! Delete LIST widget
370 END
