Example: XY Graph Shared Traces
|
10 ! *********************************************************************
20 ! Example: XY GRAPH Shared Traces
30 !
40 ! This program shows one way to generate several
50 ! traces using a single set of data.
60 !
70 ! NOTE
80 !
90 ! To exit this program, type stop or press CONTINUE.
100 !
110 ! *******************************************************
120 !
130 ASSIGN @Graph TO WIDGET "XY GRAPH"
140 CONTROL @Graph;SET ("TITLE":" Example: XY GRAPH Shared Traces")
150 CONTROL @Graph;SET ("SHARED X":1,"TRACE COUNT":20)
160 CONTROL @Graph;SET ("CURRENT TRACE":0,"POINT CAPACITY":101,"TRACE VISIBLE":0)
170 CONTROL @Graph;SET ("CURRENT AXIS":"X","AUTOSCALE":1)
180 CONTROL @Graph;SET ("CURRENT AXIS":"Y","AUTOSCALE":1)
190 !
200 INTEGER I,J,X(0:100)
210 FOR I=0 TO 100
220 X(I)=I*2
230 NEXT I
240 CONTROL @Graph;SET ("CURRENT TRACE":1,"X DATA":X(*))
250 DIM Y(0:100)
260 FOR I=1 TO 20
270 FOR J=0 TO 100
280 Y(J)=I+SIN((I+I/4)*J*PI/50)
290 NEXT J
300 CONTROL @Graph;SET ("CURRENT TRACE":I,"Y DATA":Y(*))
310 NEXT I
320 CONTROL @Graph;SET ("CURRENT TRACE":0,"TRACE VISIBLE":1)
330 PAUSE
340 !
350 Finis: !
360 ASSIGN @Graph TO * ! Delete XY GRAPH widget
370 END
